SetDirectory["~/KappaLib/"];
<<kappaLib-1.2.m
<<helper.m

In this notebook we define a medium kappa such that:

1) kappa is algebraically decomposable

2) beta^2-alpha gamma = 0

3) the Fresnel polynomial always has a linear factor, but it does not factorise 
into a product of two second order polynomials

Define medium

kappa=emMatrixToKappa[(({{-3, 1, 1, 1, 0, 0}, {0, 1, 0, 0, 0, 0}, {0, 1, 0, 0, 1, 0}, {1, 0, 0, 1, 0, 0}, {1, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 1}}))];

(* kappa is invertible *)
FullSimplify[emDet[kappa]]

(* kappa has no axion component *)
Simplify[emTrace[kappa]]

(* Since this does not simplify to {0}, kappa has a skewon component *)
Union[Flatten[kappa-emPoincare[kappa]]]

(* Since this does not simplify to {0}, kappa has a principal component *)
Union[Flatten[kappa+emPoincare[kappa]]]

Define constants alpha, beta, gamma and bivectors A and B:

alpha= 1;
beta = -1;
gamma=1;
rho=1/2;
Abivector=(({{0, 1, 0, 0}, {-1, 0, 0, 0}, {0, 0, 0, 0}, {0, 0, 0, 0}}));
Bbivector=(({{0, -4, 1, 1}, {4, 0, 0, 0}, {-1, 0, 0, 1}, {-1, 0, -1, 0}}));

Note these satisfy beta^2-alpha gamma = 0

beta^2-alpha gamma

Verify that kappa is algebraically decomposable:

LHS =alpha emIdentityKappa[] + beta (kappa +emPoincare[kappa]) + gamma emCompose[emPoincare[kappa],kappa]; 
RHS=emBiProduct[rho,Abivector,Bbivector]+emBiProduct[rho,Bbivector,Abivector];
Union[Simplify[Flatten[(LHS-RHS)]]]

Compute Fresnel polynomial

coords={xi0,xi1,xi2,xi3};
fresnel=FullSimplify[emKappaToFresnel[kappa,coords]]

Fresnel polynomial is product of linear factor and 3rd order factor

factor1=xi2;
factor2=(xi0 (xi1 (xi0+xi1)+2 (xi0+3 xi1) xi2+(xi2^2))-((xi1^2)+xi1 xi2+xi2 (3 xi0+xi2)) xi3+xi2 (xi3^2));
Simplify[fresnel-factor1 factor2]

Show that the Fresnel polynomial does not factor into a product of two second order
polynomials

gPlus=emMatrix["g",4,Structure->"Symmetric"];
gMinus=emMatrix["h",4,Structure->"Symmetric"];
gPlus//MatrixForm
gMinus//MatrixForm
factorised=(coords.gPlus.coords) (coords.gMinus.coords);

constraints=Union[Flatten[CoefficientList[factorised-fresnel,coords]]];
constraints=simp[constraints];
show[constraints]

If the Fresnel polynomial factorises the above equations must have a solution g_ij and h_ij.

By D.Cox, J.Little, D.O’Shea “Ideals, Varieties, and Algorithms” we know that a system of polynomial equations do not have have a solution (in the complex domain) if a Gröbner basis for the equations is {1}. This is the case here:

gb=GroebnerBasis[constraints,Variables[constraints]];//Timing

gb

Thus equations ‘constraints’ have no solution for h_ij and g_ij and there is no factorisation for the Fresnel surface of kappa into quadratic forms.

Show that D=A satisfies the equation

   D (kappa + beta Id) = 1/2 trace (rho bar(D) otimes D)  A + B.

(*
 * If D=1/2 D^ij d/dx^i /\ d/dx^j is a bivector we represent 
 * the coefficients by the anti-symmetric matrix with coefficients 
 * of (D^ij)_ij. If kappa is an antisymmetric (2,2)-tensor,
 * then this routine returns coefficients of bivector D (kappa).
 *)
contract[biv_,kappa_] := Table[
 1/2 Sum[biv[[i]][[j]]emReadNormal[kappa,a,b,i,j]
      ,
      {i, 1, 4},{j, 1, 4}
    ]
 ,
 {a, 1, 4}, {b, 1, 4}
]

Dbivector=Abivector;
dLHS = contract[Dbivector,kappa+beta emIdentityKappa[]];
dRHS = 1/2 emTrace[emBiProduct[rho,Dbivector,Dbivector]]Abivector+Bbivector;
deqs=Union[Flatten[Simplify[dLHS-dRHS]]]