SetDirectory["~/writing/WIP/KappaLib/"];
<<kappaLib.m

Proof of Proposition 2.2

Extra routines

(*
 *  Convert a list of expressions into equations.
 *)
toEqs[c_] := Table[c[[i]] == 0, {i, 1, Length[c]}]

(* return conditions on kappa that must be satisified if kappa is of purely skewon type (kappa in W) *)
emSkewonConditions[kappa_]:=Module[
{conditions,i,j,l,m,p,q},

conditions = Table[
Sum[emReadNormal[kappa,i,j,l,m]Signature[{l,m,p,q}],{l,1,4},{m,1,4}]
+
Sum[emReadNormal[kappa,p,q,l,m]Signature[{l,m,i,j}],{l,1,4},{m,1,4}],
{i,1,4},{j,1,4},{p,1,4},{q,1,4}
];

Union[Flatten[conditions]]

]

(* return conditions on kappa that must be satisified if kappa is of purely principal type (kappa in Z) *)
emPrincipalConditions[kappa_]:=Module[
{conditions,i,j,l,m,p,q},

conditions = Table[
Sum[emReadNormal[kappa,i,j,l,m]Signature[{l,m,p,q}],{l,1,4},{m,1,4}]
-
Sum[emReadNormal[kappa,p,q,l,m]Signature[{l,m,i,j}],{l,1,4},{m,1,4}],
{i,1,4},{j,1,4},{p,1,4},{q,1,4}
];

Append[Union[Flatten[conditions]],emTrace[kappa]]

]

Claim 1: σ(W’) subset W

Step 1: Let eta0 be trace-free (1,1)-tensor

eta=(({{w11, w12, w13, w14}, {w21, w22, w23, w24}, {w31, w32, w33, w34}, {w41, w42, w43, w44}}));
eta0=eta-1/4Tr[eta]IdentityMatrix[4];
eta0//MatrixForm

Simplify[Tr[eta0]]

Step 2: Define σ(η)

sigma[w_]:=Module[

{res,i,j,l,m},

res=emZeroKappa[];

For[i=1,i≤4,i++,
For[j=i+1,j≤4,j++,
For[l=1,l≤4,l++,
For[m=l+1,m≤4,m++,

res[[i]][[j]][[l]][[m]]= 1/2 (
w[[i]][[l]]KroneckerDelta[j,m]
-w[[j]][[l]]KroneckerDelta[i,m]
-w[[i]][[m]]KroneckerDelta[j,l]
+w[[j]][[m]]KroneckerDelta[i,l]
)

];
];
];
];

res

]

Step 3: Show that σ(η) is purely skewon.

kappa=sigma[eta0];

emSkewonConditions[kappa]

Claim 2: For any kappa in W we have kappa = σ( slashKappa), where slashKappa is the “first trace” of kappa. That is, the trace-free (1,1)-tensor

          L^i_j = kappa^is_js - 1/2 Trace(kappa) delta^i_j.

Step 1: Define arbitrary kappa

kMat=(({{k11, k12, k13, k14, k15, k16}, {k21, k22, k23, k24, k25, k26}, {k31, k32, k33, k34, k35, k36}, {k41, k42, k43, k44, k45, k46}, {k51, k52, k53, k54, k55, k56}, {k61, k62, k63, k64, k65, k66}}));
kappa=emMatrixToKappa[kMat];

Step 2: Derive conditions that coefficients of kappa should satisfy when kappa is purely skewon (that is in W)

conditions = emSkewonConditions[kappa]

Step 3: Compute kappa2 = sigma(slashKappa) and show that kappa = kappa2

emSlashKappa[kappa_]:=Module[{i,j},
Table[
Sum[emReadNormal[kappa,i,s,j,s],{s,1,4}],
{i,1,4},{j,1,4}
]-2 emTrace[kappa] 1/4IdentityMatrix[4]
]

Simplify[Tr[emSlashKappa[kappa]]]

kappa2=Simplify[sigma[emSlashKappa[kappa]]];
emKappaToMatrix[kappa2]//MatrixForm

eqs=Union[Flatten[kappa2-kappa]]

Union[Simplify[eqs,toEqs[conditions]]]

Claim 3: If σ(eta)=0 then eta = 0.

eta=(({{w11, w12, w13, w14}, {w21, w22, w23, w24}, {w31, w32, w33, w34}, {w41, w42, w43, w44}}));
eta0=eta-1/4Tr[eta]IdentityMatrix[4];
Tr[eta0]

(* We assume that σ(eta0)=0. *)
eqs=Simplify[Union[Flatten[sigma[eta0]]]]

Union[Flatten[Simplify[eta0,toEqs[eqs]]]]

Claim 4: If kappa is an arbitrary (twisted) (2,2)-tensor and

   kappa III = 1/6 trace(kappa) Id
   kappa II = sigma(slashKappa(kappa))
   kappaI = kappa - kappaII - kappaIII
    
then kappaI is in Z, kappaII is in W and kappaIII is in U.

kMat=(({{k11, k12, k13, k14, k15, k16}, {k21, k22, k23, k24, k25, k26}, {k31, k32, k33, k34, k35, k36}, {k41, k42, k43, k44, k45, k46}, {k51, k52, k53, k54, k55, k56}, {k61, k62, k63, k64, k65, k66}}));
kappa=emMatrixToKappa[kMat];

kappaIII=1/6  emTrace[kappa]emIdentityKappa[];
kappaII=sigma[emSlashKappa[kappa]];
kappaI = kappa-kappaII-kappaIII;

Union[Simplify[emSkewonConditions[kappaII]]]
Union[Simplify[emPrincipalConditions[kappaI]]]