In this notebook we check a number of standard results for the Levi-Civita permutation symbol
and matrices.

Claim 1:

   epsilon^ijk   epsilon_mnk   = delta^i_m delta^j_n - delta^i_n delta^j_m.
   
   Here i, j, m, n are in {1,2,3} and on the LHS k is summed over 1,2,3.

tTable = Table[ Sum[Signature[{i,j,k}] Signature[{m,n,k}], {k,1,3}] == (KroneckerDelta[i,m] KroneckerDelta[j,n]-KroneckerDelta[i,n]KroneckerDelta[j,m]), {i,1,3},{j,1,3},{m,1,3},{n,1,3}];

tTable = Union[Flatten[tTable]]

Claim 2: 

If A is a 3x3 matrix then

      epsilon_abc    A^a_i  A^b_j  A^c_k = det(A) epsilon_ijk

A={{a11,a12,a13},
{a21,a22,a23},
{a31,a32,a33}};
A//MatrixForm

LHS[i_,j_,k_]:=Sum[
Signature[{a,b,c}] A[[a]][[i]] A[[b]][[j]] A[[c]][[k]],{a,1,3},{b,1,3},{c,1,3}
]

RHS[i_,j_,k_]:=Det[A]Signature[{i,j,k}]

tTable=Table[
RHS[i,j,k]==LHS[i,j,k],
{i,1,3},{j,1,3},{k,1,3}];
Union[Flatten[tTable]]

Claim 3: epsilon_ijk epsilon^ijk = 3!

Sum[Signature[{i,j,k}]Signature[{i,j,k}],{i,1,3},{j,1,3},{k,1,3}]

Claim 4: 

If A is a 4x4 matrix then

      epsilon_abcd    A^a_i  A^b_j  A^c_k A^d_l= det(A) epsilon_ijkl

A={{a11,a12,a13,a14},
{a21,a22,a23,a24},
{a31,a32,a33,a34},
{a41, a42,a43,a44}
};
A//MatrixForm

LHS[i_,j_,k_,l_]:=Sum[
Signature[{a,b,c,d}] A[[a]][[i]] A[[b]][[j]] A[[c]][[k]]A[[d]][[l]],
{a,1,4},{b,1,4},{c,1,4},{d,1,4}
]

RHS[i_,j_,k_,l_]:=Det[A]Signature[{i,j,k,l}]

tTable=Table[
RHS[i,j,k,l]==LHS[i,j,k,l],
{i,1,4},{j,1,4},{k,1,4},{l,1,4}
];
Union[Flatten[tTable]]

Claim 5: In 4-dimensions 

	epsilon^abrs   epsilon_abmn = 2 (delta^r_m delta^s_n - delta^r_n delta^s_m)

tTable =Table[
Sum[Signature[{a,b,r,s}]Signature[{a,b,m,n}],{a,1,4},{b,1,4}]==2( KroneckerDelta[r,m] KroneckerDelta[s,n]-KroneckerDelta[r,n] KroneckerDelta[s,m])
,
{r,1,4},{s,1,4},{m,1,4},{n,1,4}
];
Union[Flatten[tTable]]

Claim 6: In 4 dimensions

        epsilon^sabc epsilon_sijkl = 3! delta^a_[i delta^b_j delta^c_k]

d[i_,j_]:=KroneckerDelta[i,j]

Permutations[{i,j,k}]

tTable =Table[
Sum[Signature[{s,a,b,c}]Signature[{s,i,j,k}],{s,1,4}]
-
( 
d[a,i]d[b,j]d[c,k]
-d[a,i]d[b,k]d[c,j]
-d[a,j]d[b,i]d[c,k]
+d[a,j]d[b,k]d[c,i]
+d[a,k]d[b,i]d[c,j]
-d[a,k]d[b,j]d[c,i]
)
,
{i,1,4},{j,1,4},{k,1,4},{a,1,4},{b,1,4},{c,1,4}
];

Union[Flatten[tTable]]