Värähtelyliike L11maple.mws

ti 29.10.02 HA

Kirjallisuus:

 KRE  2.2  s. 72 ->  2. kl. vakiokertoimiset,  (2. asteen yhtälön juuret => 3 eri tapausta)

      Mallinnusta: (Sama uudelleen fysikaalisin tulkinnoin, mekaaniset värähtelyt, sähkövärähtelyt)

           2.5 s. 83 -> Vapaat värähtelyt (Free oscillations)

           2.11 s. 111 -> Pakotetut värähtelyt (Forced oscillations)

 1. Vapaa vaimentamaton , eli harmoninen värähtely (HY)

>    restart: 

Warning, the name changecoords has been redefined

>    dyht:=diff(y(t),t,t)+w0^2*y(t)=0;

dyht := diff(y(t),`$`(t,2))+w0^2*y(t) = 0

>    w0yht:=w0=sqrt(k/m): # T:=2*Pi/w0: f0:=1/T:  # assign(w0yht): antaa ko. arvon w0:lle.

>   

Tiedämme entuudestaan ja näemme suoraan yhtälöstä, että alla oleva on yleinen ratkaisu. Antaa nyt Maplenkin vielä laskea:

>    y:=A*cos(w0*t)+B*sin(w0*t);

y := A*cos(w0*t)+B*sin(w0*t)

>    diff(y,t,t)+w0^2*y;

-A*cos(w0*t)*w0^2-B*sin(w0*t)*w0^2+w0^2*(A*cos(w0*t)+B*sin(w0*t))

>    simplify(%);

0

Alkuehdot vaikkapa:  y(0)=1, y'(0)=0.

>    AE:={subs(t=0,y)=1,subs(t=0,diff(y,t))=0};

AE := {-A*sin(0)*w0+B*cos(0)*w0 = 0, A*cos(0)+B*sin(0) = 1}

>    vakiot:=solve(AE,{A,B});

vakiot := {A = 1, B = 0}

>    Y:=subs(vakiot,y);

Y := cos(w0*t)

>    assign(w0yht): w0;

(k/m)^(1/2)

>    k:=2: m:=1: w0; Y;   # k on jousivakio, m on massa.

2^(1/2)

cos(2^(1/2)*t)

>    plot(Y,t=0..2*Pi/w0);

[Maple Plot]

Tämän mallin pohjalta on helppo tehdä erilaisia tapauksia. Muutellaan vain parametrejä

k ja m sekä alkuehtoja.  

Amplitudi ja vaihekulma nähdään muodosta ,   y = C*cos(omega[0]*t-delta)  .

>    A:='A': B:='B':

>    C:=sqrt(A^2+B^2); delta:=arctan(B,A);

C := (A^2+B^2)^(1/2)

delta := arctan(B,A)

"Kiintoisammat" alkuehdot, kuten y(0)=1, y'(0)=2 .

>    AE:={subs(t=0,y)=1,subs(t=0,diff(y,t))=2};

AE := {A*cos(0)+B*sin(0) = 1, -A*sin(0)*2^(1/2)+B*cos(0)*2^(1/2) = 2}

>    vakiot:=solve(AE,{A,B});

vakiot := {A = 1, B = 2^(1/2)}

>    assign(vakiot);  # Hiukan vaarallista, mutta tässä aika kätevää.

>    'C'=C, 'delta'=delta;

C = 3^(1/2), delta = arctan(2^(1/2))

>    plot(C*cos(w0*t-delta),t=0..2*2*Pi/w0,title="Kaksi jaksoa");

[Maple Plot]

  1.1. Vapaa vaimentamaton, esimerkki

Esim.

10 gramman massa venyttää jousta s[0]  = 2 cm. Massaa vedetään alaspäin 2 cm tasapainoasemastaan

ja annetaan sille alkunytkäys 1 m/s ylöspäin.

Määritä massan sijainti ajan funktiona. Määritä jakso, amplitudi ja vaihekulma.

>    restart; 

Warning, the name changecoords has been redefined

>    dyht:=diff(y(t),t,t)+(k/m)*y(t)=0;

dyht := diff(y(t),`$`(t,2))+k/m*y(t) = 0

>    k*s0=m*g; k:=solve(%,k);

k*s0 = m*g

k := m*g/s0

>    m:=10: s0:=2: g:=9.81:

>    k;

49.05000000

>    dyht;

diff(y(t),`$`(t,2))+4.905000000*y(t) = 0

>    w0:=sqrt(k/m);

w0 := 2.214723459

Yl- ratkaisu:

>    y:=A*cos(w0*t)+B*sin(w0*t);

y := A*cos(2.214723459*t)+B*sin(2.214723459*t)

>    Y:=C*cos(w0*t-delta); # Ratkaisu muodossa "amplitudi ja vaihekulma".

Y := C*cos(2.214723459*t-delta)

>    C:=sqrt(A^2+B^2); delta:=arctan(B,A);

C := (A^2+B^2)^(1/2)

delta := arctan(B,A)

>    yf:=unapply(y,t); # Määritellään lauseke funktioksi, AE-yhtälöt helpompi muodostaa.

yf := proc (t) options operator, arrow; A*cos(2.214723459*t)+B*sin(2.214723459*t) end proc

>    AE1:={yf(0)=1,D(yf)(0)=0}: solve(AE1,{A,B}): y1:=subs(%,y);

y1 := 1.*cos(2.214723459*t)

>    AE2:={yf(0)=1,D(yf)(0)=1}: solve(AE2,{A,B}): y2:=subs(%,y);

y2 := 1.*cos(2.214723459*t)+.4515236410*sin(2.214723459*t)

>    AE3:={yf(0)=1,D(yf)(0)=-1}: solve(AE3,{A,B}): y3:=subs(%,y);

y3 := 1.*cos(2.214723459*t)-.4515236410*sin(2.214723459*t)

>    T:=2*Pi/w0; w0:=sqrt(k/m): T;

T := .9030472820*Pi

.9030472820*Pi

>    plot([y1,y2,y3],t=0..2*T,color=[red,green,blue],title="Punainen:y'(0)=0,vihreä: y'(0)=1, sininen: y'(0)=-1");

>   

[Maple Plot]

Sinisellä ja vihreällä on sama amplitudi, punaisella pienempi (minimaalinen tällä alkupoikkeutuksella).

Lasketaanpa vielä:

>    solve(AE1,{A,B}); C1:=subs(%,sqrt(A^2+B^2)); delta[1]:=subs(%%,arctan(B,A));eval(%);

{A = 1., B = 0.}

C1 := 1.

delta[1] := arctan(0.,1.)

0.

>    solve(AE2,{A,B}); C2:=subs(%,sqrt(A^2+B^2)); delta[2]:=subs(%%,arctan(B,A));eval(%);

{A = 1., B = .4515236410}

C2 := 1.097211738

delta[2] := arctan(.4515236410,1.)

.4241202645

>    solve(AE3,{A,B}); C3:=subs(%,sqrt(A^2+B^2)); delta[3]:=subs(%%,arctan(B,A));eval(%);

{A = 1., B = -.4515236410}

C3 := 1.097211738

delta[3] := arctan(-.4515236410,1.)

-.4241202645

 2. Vaimennettu (vapaa) värähtely (HY)

Systeemissä on yleensä vastusta: kitkaa, ilman tai nesteen vastusta ym. Siinä voi myös olla mekaaninen iskunvaimentaja

"shock absorber", "dashpot".

Jos liike ei ole kovin nopeaa, hyvä approksimaatio saadaan olettamalla vastusvoima verrannolliseksi nopeuteen.

Vastusvoima on tietysti liikkeen suunnalle vastakkainen :

>    F[v] = -c*diff(y(t),t)

>    restart: 

Warning, the name changecoords has been redefined

Liikeyhtälö saa yleisen muodon:

>    m*diff(y(t),t,t)+c*diff(y(t),t)+k*y(t)=0;

m*diff(y(t),`$`(t,2))+c*diff(y(t),t)+k*y(t) = 0

Yrite   y(t) = exp(lambda*t)   johtaa karakteristiseen yhtälöön (kuten jo aiemmin todettiin):

>    karpol:=lambda^2+c/m*lambda+k/m;

karpol := lambda^2+c/m*lambda+k/m

>    Lambda:=solve(karpol=0,lambda);

Lambda := 1/2/m*(-c+(c^2-4*m*k)^(1/2)), 1/2/m*(-c-(c^2-4*m*k)^(1/2))

>    diskr:=c^2-4*m*k;

diskr := c^2-4*m*k

Diskriminantin merkkikäytös määrää tapaukset I, II, III .

Ylivaimennus, diskr > 0

Kaksi erillistä reaalijuurta   lambda[1]  ja lambda[2]  , yleinen ratkaisu:

>    y := C[1]*exp(lambda[1]*t)+C[2]*exp(lambda[2]*t)

Kriittinen vaimennus, diskr = 0

Reaalinen kaksoisjuuri   lambda  . Yleinen ratkaisu:

>    y := (C[1]+C[2]*t)*exp(lambda*t)

Alivaimennus, diskr < 0

Kompleksikonjugaattijuuret   lambda[1] = alpha+I*beta  , lambda[2] = alpha-I*beta  . Yleinen ratkaisu:

>    y := exp(alpha*t)*(A*cos(beta*t)+B*sin(beta*t))

  2.1. Esimerkkejä vapaasta vaimennetusta liikkeestä.

Seuraavissa 3 perustapausta.

>    restart: 

Warning, the name changecoords has been redefined

>    dyht:=m*diff(y(t),t,t)+c*diff(y(t),t)+k*y(t)=0;

dyht := m*diff(y(t),`$`(t,2))+c*diff(y(t),t)+k*y(t) = 0

>    karyht:=m*lambda^2+c*lambda+k=0;diskr:=c^2-4*m*k;

karyht := m*lambda^2+c*lambda+k = 0

diskr := c^2-4*m*k

Pidetään m ja k samoina ja muutellaan vaimennuskerrointa c .

>    m:=9.082:k:=890:

1. Ylivaimennus

>    c:=200:

>    karyht;

9.082*lambda^2+200*lambda+890 = 0

>    Lambda:=solve(karyht,lambda);

Lambda := -6.189849488, -15.83173166

>    y:=C1*exp(Lambda[1]*t)+C2*exp(Lambda[2]*t);

y := C1*exp(-6.189849488*t)+C2*exp(-15.83173166*t)

AE: y(0)=0.15, y'(0)=0 .

>    AE:={subs(t=0,y)=0.15,subs(t=0,diff(y,t))=0};

AE := {C1*exp(0.)+C2*exp(0.) = .15, -6.189849488*C1*exp(0.)-15.83173166*C2*exp(0.) = 0}

>    solve(AE,{C1,C2});

{C1 = .2462962839, C2 = -.9629628392e-1}

>    Y:=subs(%,y);

Y := .2462962839*exp(-6.189849488*t)-.9629628392e-1*exp(-15.83173166*t)

>    plot(Y,t=0..1);

[Maple Plot]

2. Kriittinen vaimennus

>    lambda:='lambda':

>    c:=179.81078: diskr;

-.340e-2

>    karyht;

9.082*lambda^2+179.81078*lambda+890 = 0

>    Lambda:=solve(karyht,lambda);

Lambda := -9.899294208+.3208182176e-2*I, -9.899294208-.3208182176e-2*I

>    lambda:=Re(Lambda[1]);

lambda := -9.899294208

>    y:=(C1+C2*t)*exp(lambda*t);

y := (C1+C2*t)*exp(-9.899294208*t)

Kriittinen vaimennus on tietysti ideaalitapaus, käytännön laskuissa tulee yleensä pieni imag. termi tai sitten pieni ero reaalisten lambdojen välillä.

Tässä saadaan hyvä approksimaatio jättämällä pienet imaginaariosat pois.

Alkuehdot: y(0)=0.15, y'(0)=-0.2    

>    AE:=subs(t=0,y)=0.15,subs(t=0,diff(y,t))=-1.8;

AE := C1*exp(0.) = .15, C2*exp(0.)-9.899294208*C1*exp(0.) = -1.8

>    solve({AE},{C1,C2});

{C2 = -.3151058688, C1 = .1500000000}

>    Y:=subs(%,y);

Y := (.1500000000-.3151058688*t)*exp(-9.899294208*t)

>   

>    plot(Y,t=0..5,view=[0.3..1,-0.002..0.002]);

[Maple Plot]

>   

3. Alivaimennus

>    lambda:='lambda':

>    c:=100:

>    karyht;Lambda:=solve(karyht,lambda);

9.082*lambda^2+100*lambda+890 = 0

Lambda := -5.505395287+8.227190216*I, -5.505395287-8.227190216*I

>    lambda:=Lambda[1]:alpha:=Re(lambda);w1:=abs(Im(lambda));

alpha := -5.505395287

w1 := 8.227190216

w1 on KRE:n omega*

>    y:=exp(alpha*t)*(A*cos(w1*t)+B*sin(w1*t));

y := exp(-5.505395287*t)*(A*cos(8.227190216*t)+B*sin(8.227190216*t))

>    AE:=subs(t=0,y)=0.15,subs(t=0,diff(y,t))=0;

AE := exp(0.)*(A*cos(0.)+B*sin(0.)) = .15, -5.505395287*exp(0.)*(A*cos(0.)+B*sin(0.))+exp(0.)*(-8.227190216*A*sin(0.)+8.227190216*B*cos(0.)) = 0
AE := exp(0.)*(A*cos(0.)+B*sin(0.)) = .15, -5.505395287*exp(0.)*(A*cos(0.)+B*sin(0.))+exp(0.)*(-8.227190216*A*sin(0.)+8.227190216*B*cos(0.)) = 0

>    solve({AE},{A,B});

{B = .1003756169, A = .1500000000}

>    Y:=subs(%,y);

Y := exp(-5.505395287*t)*(.1500000000*cos(8.227190216*t)+.1003756169*sin(8.227190216*t))

>    plots[display](array([[plot(Y,t=0..4)],[plot(Y,t=0.5..3)],[plot(Y,t=1..3)]]));

[Maple Plot]

>    plot(Y,t=0..4,view=[0..4,-0.02..0.02],axes=boxed);

[Maple Plot]

 3. Pakotettu värähtely, (EHY)

>    restart: 

Warning, the name changecoords has been redefined

>    dyht:=m*diff(x(t),t,t)+c*diff(x(t),t)+k*x(t)=F0*cos(w*t);

dyht := m*diff(x(t),`$`(t,2))+c*diff(x(t),t)+k*x(t) = F0*cos(w*t)

Käytetään omega :n sijasta w :tä, koska omega0 ei ole hauska.

Tapaus 1. Vaimentamaton pakkovärähtely

>    restart: 

Warning, the name changecoords has been redefined

>    diffy:=diff(y(t),t,t)+w0^2*y(t)=F0/m*cos(omega*t);

diffy := diff(y(t),`$`(t,2))+w0^2*y(t) = F0/m*cos(omega*t)

>    yp:=a*cos(omega*t)+b*sin(omega*t);

yp := a*cos(omega*t)+b*sin(omega*t)

>    yht:=eval(subs(y(t)=yp,diffy));

yht := -a*cos(omega*t)*omega^2-b*sin(omega*t)*omega^2+w0^2*(a*cos(omega*t)+b*sin(omega*t)) = F0/m*cos(omega*t)

>    yht:={map(coeff,yht,cos(omega*t)),map(coeff,yht,sin(omega*t))};

yht := {-a*omega^2+w0^2*a = F0/m, -b*omega^2+w0^2*b = 0}

>    yht:=solve(yht,{a,b});

yht := {b = 0, a = F0/m/(-omega^2+w0^2)}

>    yp:=subs(yht,yp);

yp := F0/m/(-omega^2+w0^2)*cos(omega*t)

Tämä siis pätee, jos omega  # w0.

Ei resonanssi , eli omega <> omega[0]

>    yh:=C*cos(w0*t-delta);     

yh := C*cos(w0*t-delta)

>    w0=sqrt(k/m); # Emme tee sijoitusta, muistutamme vain

w0 = (k/m)^(1/2)

>    yp;

F0/m/(-omega^2+w0^2)*cos(omega*t)

>    y:=yh+yp;   

y := C*cos(w0*t-delta)+F0/m/(-omega^2+w0^2)*cos(omega*t)

Mitä tapahtuu, kun omega  -> w0 ?

Resonanssi, omega = omega[0]

Nyt äskeinen yrite ei toimi, sillä se toteuttaa (HY):n, eikä siten millään voi toteuttaa EHY:ä.

>    restart: 

Warning, the name changecoords has been redefined

Pulmatilanteissa t:llä kertominen on tuottanut hyvän yritteen, Niinpä kannattaa ainakin yrittää: (KRE: "mofifcation rules", kohta 2.9.)

>    yp:=t*(a*cos(w0*t)+b*sin(w0*t));

yp := t*(a*cos(w0*t)+b*sin(w0*t))

>    yhtalo:=simplify(diff(yp,t,t)+w0^2*yp)=F0*cos(w0*t)/m;

yhtalo := -2*w0*(a*sin(w0*t)-b*cos(w0*t)) = F0*cos(w0*t)/m

>    map(coeff,yhtalo,sin(w0*t)),map(coeff,yhtalo,cos(w0*t));

-2*w0*a = 0, 2*w0*b = F0/m

>    solve({%},{a,b});assign(%):

>    a,b;

{a = 0, b = 1/2*F0/w0/m}

0, 1/2*F0/w0/m

>    yp;

1/2*t*F0/w0/m*sin(w0*t)

>    m:=1:F0:=1:w0:=10:

>    plot(yp,t=0..30);

[Maple Plot]

>   

Huojunta, beats

Lue KRE ss. 114 - 115. Tästä ehkä harj. teht.

 Tapaus 2. Vaimennettu pakkovärähtely

Ol: c > 0, c^2 < 4*m*k .

>    restart: 

Warning, the name changecoords has been redefined

>    dyht:=m*diff(y(t),t,t)+c*diff(y(t),t)+k*y(t)=F0*cos(omega*t);

dyht := m*diff(y(t),`$`(t,2))+c*diff(y(t),t)+k*y(t) = F0*cos(omega*t)

EHY-yrite:

>    yp:=a*cos(omega*t)+b*sin(omega*t);

yp := a*cos(omega*t)+b*sin(omega*t)

>    yht:=eval(subs(y(t)=yp,dyht));

yht := m*(-a*cos(omega*t)*omega^2-b*sin(omega*t)*omega^2)+c*(-a*sin(omega*t)*omega+b*cos(omega*t)*omega)+k*(a*cos(omega*t)+b*sin(omega*t)) = F0*cos(omega*t)

>    yht:={map(coeff,yht,cos(omega*t)),map(coeff,yht,sin(omega*t))};

yht := {-m*a*omega^2+c*b*omega+k*a = F0, -m*b*omega^2-c*a*omega+k*b = 0}

>    yht:=solve(yht,{a,b});

yht := {b = c*omega*F0/(c^2*omega^2+m^2*omega^4-2*m*omega^2*k+k^2), a = -(m*omega^2-k)*F0/(c^2*omega^2+m^2*omega^4-2*m*omega^2*k+k^2)}

Lausekkeita voidaan vähän sieventää ottamalla omega[0]^2 = k/m  käyttöön (vrt. KRE kaavat (5) s. 113.

Tarvitsemme yleisiä kaavoja etupäässä siihen tietoon, että kertoimet a ja b voidaan aina määrätä. (Olipa omega = omega[0] tai ei.).

Yleisistä kaavoista saadaan myös resonanssityylinen kaava asettamalla vain omega = omega[0]  . Toisaalta Maple tekee

johtamisen puolestamme, kuten edelläkin.

>    restart: 

Warning, the name changecoords has been redefined

>    dyht:=diff(y(t),t,t)+c/m*diff(y(t),t)+w0^2*y(t)=F0/m*cos(w0*t);

dyht := diff(y(t),`$`(t,2))+c/m*diff(y(t),t)+w0^2*y(t) = F0/m*cos(w0*t)

EHY-yrite:

>    yp:=a*cos(w0*t)+b*sin(w0*t);

yp := a*cos(w0*t)+b*sin(w0*t)

>    yht:=eval(subs(y(t)=yp,dyht));

yht := -a*cos(w0*t)*w0^2-b*sin(w0*t)*w0^2+c/m*(-a*sin(w0*t)*w0+b*cos(w0*t)*w0)+w0^2*(a*cos(w0*t)+b*sin(w0*t)) = F0/m*cos(w0*t)
yht := -a*cos(w0*t)*w0^2-b*sin(w0*t)*w0^2+c/m*(-a*sin(w0*t)*w0+b*cos(w0*t)*w0)+w0^2*(a*cos(w0*t)+b*sin(w0*t)) = F0/m*cos(w0*t)

>    yht:={map(coeff,yht,cos(w0*t)),map(coeff,yht,sin(w0*t))};

yht := {c/m*b*w0 = F0/m, -c/m*a*w0 = 0}

>    yht:=solve(yht,{a,b});

yht := {b = F0/c/w0, a = 0}

>   

>   

>   

>    yp:=subs(yht,yp);

yp := F0/c/w0*sin(w0*t)

Jos vaimennusvakio on pieni, niin amplitudi on suuri, mutta pysyy kuitenkin äärellisenä, kun kerran vaimennusta on (c > 0).

Kun c --> 0, niin amplitudi kasvaa rajatta, jolloin lähestytään vaimentamatonta resonanssitapausta.

Esim.

>    restart: 

Warning, the name changecoords has been redefined

>    EHY:=m*diff(y(t),t,t)+c*diff(y(t),t)+k*y(t)=10*cos(omega*t);

EHY := m*diff(y(t),`$`(t,2))+c*diff(y(t),t)+k*y(t) = 10*cos(omega*t)

>    HY:=lhs(EHY)=0:HY:=subs(m=1,c=4,k=24,HY);

HY := diff(y(t),`$`(t,2))+4*diff(y(t),t)+24*y(t) = 0

>    lambda^2+4*lambda+24=0; solve(%,lambda);

lambda^2+4*lambda+24 = 0

-2+2*I*5^(1/2), -2-2*I*5^(1/2)

Siis kompleksijuuret (alivaimennus), joten värähtelyä on luvassa.

Tästä nähdään heti HY:n yleinen.  Demonstroidaan tässä kuitenkin annetaan Maplen yleistä diffyht.ratkaisijaa dsolve :a.

>    dsolve(HY,y(t));

y(t) = _C1*exp(-2*t)*sin(2*5^(1/2)*t)+_C2*exp(-2*t)*cos(2*5^(1/2)*t)

>    yh:=rhs(%);

yh := _C1*exp(-2*t)*sin(2*5^(1/2)*t)+_C2*exp(-2*t)*cos(2*5^(1/2)*t)

EHY-yrite:

>    yp:=a*cos(omega*t)+b*sin(omega*t);

yp := a*cos(omega*t)+b*sin(omega*t)

>    yht:=eval(subs(y(t)=yp,EHY));

yht := m*(-a*cos(omega*t)*omega^2-b*sin(omega*t)*omega^2)+c*(-a*sin(omega*t)*omega+b*cos(omega*t)*omega)+k*(a*cos(omega*t)+b*sin(omega*t)) = 10*cos(omega*t)

>    yht:={map(coeff,yht,cos(omega*t)),map(coeff,yht,sin(omega*t))};

yht := {-m*a*omega^2+c*b*omega+k*a = 10, -m*b*omega^2-c*a*omega+k*b = 0}

>    yht:=subs(m=1,c=4,k=24,yht);

yht := {-a*omega^2+4*b*omega+24*a = 10, -b*omega^2-4*a*omega+24*b = 0}

>    yht:=solve(yht,{a,b});

yht := {a = -10*(omega^2-24)/(-32*omega^2+omega^4+576), b = 40*omega/(-32*omega^2+omega^4+576)}

>    assign(m=1,c=4,k=24);

>    w0:=sqrt(k/m);

w0 := 2*6^(1/2)

>    omega:=w0/2;

omega := 6^(1/2)

>    yp;

a*cos(6^(1/2)*t)+b*sin(6^(1/2)*t)

>    yp:=subs(yht,yp);

yp := 3/7*cos(6^(1/2)*t)+2/21*6^(1/2)*sin(6^(1/2)*t)

>    yh;

_C1*exp(-2*t)*sin(2*5^(1/2)*t)+_C2*exp(-2*t)*cos(2*5^(1/2)*t)

>    y:=unapply(yh+yp,t);

y := proc (t) options operator, arrow; _C1*exp(-2*t)*sin(2*5^(1/2)*t)+_C2*exp(-2*t)*cos(2*5^(1/2)*t)+3/7*cos(6^(1/2)*t)+2/21*6^(1/2)*sin(6^(1/2)*t) end proc

>   

>    AE:={y(0)=0.15,D(y)(0)=0};

AE := {3/7+_C2 = .15, 4/7+2*_C1*5^(1/2)-2*_C2 = 0}

>    kertoimet:=solve(AE,{_C1,_C2});

kertoimet := {_C2 = -.2785714286, _C1 = -.2523562432}

>    assign(%):

>    y(t);

-.2523562432*exp(-2*t)*sin(2*5^(1/2)*t)-.2785714286*exp(-2*t)*cos(2*5^(1/2)*t)+3/7*cos(6^(1/2)*t)+2/21*6^(1/2)*sin(6^(1/2)*t)

>    yh,yp;

-.2523562432*exp(-2*t)*sin(2*5^(1/2)*t)-.2785714286*exp(-2*t)*cos(2*5^(1/2)*t), 3/7*cos(6^(1/2)*t)+2/21*6^(1/2)*sin(6^(1/2)*t)

>    plot([yh,yp,yh+yp],t=0..8,color=[red,green,blue],title="Punainen transientti,vihreä: tasapainotila, sininen: yh+yp");

[Maple Plot]

>    plot([yh+yp],t=0..8,color=[blue],title="Koko ratkaisu yh+yp");

[Maple Plot]

>   

>   

  • Punainen y[h]  edustaa alkuehdoista riippuvaa "transienttia"  osaa,joka kestää vain hetken ja sammuu pian pois.
  • Vihreä y[p] edustaa pysyvää, " steady state ",  (dynaamista) tasapainotilaratkaisua , joka jää, kun aikaa kuluu (kun transientti on
    kuollut pois (käytännöllisesti  katsoen).
  • Sininen on koko ratkaisu, joka selvästikään ei juuri erotu vihreästä, kun aikaa kuluu.