Tehtävä 1

D[f[g[x]], x]
D[f[g[x]], {x, 2}]
D[f[g[x]], {x, 3}]

Tehtävä 2

lst = Table[D[Tan[x], {x, i}], {i, 1, 20}]

lst[[10]]

lst[[10]] /. x -> 0

Tehtävä 3

deri = D[x == y[x]^3 + y[x]^2 + y[x] + 1, x]

Solve[deri /. {x -> 0, y[x] -> -1}, y'[0]]

ParametricPlot[{y^3 + y^2 + y + 1, y}, {y, -2, 2}, 
      PlotRange -> {{-2, 2}, {-2, 2}}, 
      AspectRatio -> Automatic]

Tehtävä 4

f[x_] = ArcTan[x] + ArcTan[(1 - x)/(1 + x)]

Simplify[D[f[x], x]]

Kuitenkaan funktio ei ole vakio!

Plot[f[x], {x, -3, 3}, PlotRange -> {-3, 2}]

Tehtävä 5

f[x_] = 
        x^4 - 7  x^3 + 11  x^2 + 7  x - 10;
f1[x_] = D[f[x], x];
f2[x_] = D[f[x], {x, 2}];

Plot[f[x], {x, -1.5, 5}]

Nollakohdat:

NSolve[f[x] == 0, x]

Ääriarvopisteet:

rat2 = Solve[f1[x] == 0, x]

apist = 
      Table[{x /. rat2[[i]], f[x] /. rat2[[i]]}, {i, 1, 3}] // 
        N

% // Chop

Käännepisteet:

rat3 = Solve[f2[x] == 0, x]

kpist = Table[{x /. rat3[[i]], f[x] /. rat3[[i]]}, {i, 1, 
              2}] // N // Chop

Tehtävä 6

f[x_] = 2*x^4 - 12*x^3 + 7*x^2 + 41*x - 3; 
    Plot[f[x], {x, -2, 4.5}]

rat = NSolve[f[x] == 0, x]

Integrate[-f[x], {x, x /. rat[[1]], 
        x /. rat[[2]]}]

Tehtävä 7

f[x_] = Sin[x]^2;

Tilavuus:

Integrate[Pi*f[x]^2, {x, 0, Pi}]

% // N

Pinta-ala

Integrate[2*Pi*f[x] Sqrt[1 + f'[x]^2], {x, 0, Pi}]

% // N

ParametricPlot3D[{x, Sin[x]^2*Sin[t], Sin[x]^2*Cos[t]}, {x, 0, 
          Pi}, {t, 0, 2*Pi}];

Tehtävä 8

f[x_] = ArcSin[2  x*Sqrt[1 - x^2]];
Plot[f[x], {x, -1, 1}, AspectRatio -> Automatic]

Suljetulla välillä jatkuva funktio: ääriarvot saadaan joko päätepisteissä, derivaatan nollakohdissa tai derivaatan epäjatkuvuuskohdissa.

f[-1]

    f[1]

f1[x_]=Simplify[D[f[x], x]]

rat1=Solve[f1[x] == 0, 
        x]

rat2 = Solve[Denominator[f1[x]] == 0, x]

Pienin arvo ja suurin arvo:

f[x /. rat2[[3]]]
f[x /. rat2[[4]]]

Tehtävä 9

<< Graphics`ImplicitPlot`

ImplicitPlot[{y^2 == x, x - y == 3}, {x, 0, 6}]

f[y_] = y^2; g[y_] = 3 + y;

rat = Solve[f[y] == g[y], y]

Integrate[
      g[y] - f[y], {y, y /. rat[[1]], y /. rat[[2]]}]

Tehtävä 10

f[x_] = -4 x^2 + 40  x - 97;

Plot[f[x], {x, 3.5, 6.5}]

Vaihtoehto 1

rat1 = Solve[f[x] == 0, x]

Integrate[
      2*Pi*x*f[x], {x, x /. rat1[[1]], x /. rat1[[2]]}]

Vaihtoehto 2

rat2 = Solve[y == f[x], x]

Integrate[
      Pi*(x /. rat2[[2]])^2 - Pi*(x /. rat2[[1]])^2, {y, 0, 
        3}]