Simo K. Kivelä / 09.05.2003

Ympyrä ja pyörähdyspinta

Tehtävä 1:

Ympyrän keskipiste on origo ja säde on 2. Muodosta ympyrälle parametriesitys ja piirrä ympyrä tämän avulla.

Ratkaisu 1:

Remove["Global`*"]

Trigonometristen funktioiden määritelmistä seuraa, että origoon asetettua suuntakulmaa t vastaava piste (2 cos(t),  2 sin(t)) on etäisyydellä 2 origosta, ts. se
sijaitsee halutulla ympyrällä. Jos toisaalta t saa kaikki arvot väliltä [0,  2 π[, saadaan kaikki ympyrän pisteet.

Mallikuvio voidaan piirtää Mathematicalla:

kuvio = 
        Graphics[{Line[{{-2.5, 0}, {2.5, 0}}], 
            Line[{{0, -2.5}, {0, 2.5}}], 
            Line[{{0, 0}, {2 Cos[1], 0}, {2 Cos[1], 2 Sin[1]}, {0, 
                  0}}], Circle[{0, 0}, 2], 
            Text["2", {Cos[1], Sin[1]}, {0.5, -0.5}], 
            Text["2cos(t)", {Cos[1], 0}, {0, 1}], 
            Text["2sin(t)", {2 Cos[1], Sin[1]}, {-1, 1.5}], 
            Text["t", {Cos[1/2]/3, 
                Sin[1/2]/3}]}];
Show[kuvio, AspectRatio -> 1]

Ympyrän parametriesitykseksi siis kelpaa (2 cos(t),  2 sin(t)) ja käyrä voidaan tähän perustuen piirtää:

ParametricPlot[
      2 {Cos[t], Sin[t]}, {t, 0, 2 Pi}]

Kuvio sinänsä on oikea, mutta akseleiden yksiköt ovat eri pitkät, minkä takia tulos näyttää ellipsiltä. Asia voidaan korjata:

ParametricPlot[2 {Cos[t], Sin[t]}, {t, 0, 2 Pi}, 
      AspectRatio -> Automatic]

Tehtävä 2:

Käyrä y = ((sin(x))^2), 0 ≤ x ≤ π, pyörähtää x-akselin ympäri, jolloin syntyy pyörähdyspinta. Laske pinnan ala, sen rajaaman alueen tilavuus ja piirrä pinta.

Ratkaisu 2:

Remove["Global`*"]

Olkoon

y =  Sin[x]^2

Tilavuus saadaan integroimalla:

v = Integrate[Pi y^2, {x, 0, Pi}]

Huomaa: Sen enempää tilavuuden laskeminen kuin seuraava pinnan alan laskeminenkaan ei edellytä kaavojen ulkoa osaamista, vaan niiden ymmärtämistä. Tämän jälkeen kaavan mieleen palauttaminen ei ole minkäänlainen ongelma!

Pinta-alan integrointi:

integrandi = 2 Pi y Sqrt[1 + D[y, x]^2]

a = Integrate[integrandi, {x, 0, Pi}]

Tulosta ei voida esittää alkeisfunktioiden avulla, mutta kylläkin Mathematican tunteman erikoisfunktion avulla. Tälle voidaan laskea numeerinen arvo tavalliseen tapaan:

a // N

Vaihtoehtona on integroida suoraan numeerisesti:

NIntegrate[integrandi, {x, 0, Pi}]

Pinta voidaan parametrisoida sen perusteella, että sen leikkaus x-akselia vastaan kohtisuoran tason kanssa on ympyrä. Tälle puolestaan voidaan käyttää edellä muodostettua parametriesitystä:

pinta = {x, y Cos[t], y Sin[t]}

ParametricPlot3D[pinta, {x, 0, Pi}, {t, 0, 2 Pi}]