Simo K. Kivelä / 12.05.2003

Funktiot

Remove["Global`*"]

Valmiit funktiot

Mathematica tuntee melkoisen joukon valmiita funktioita:

Log[1.5]

Plot[Erf[x], {x, -5, 5}]

Expand[(x + y)^3]

TrigExpand[Sin[x + y]]

Nämä ovat joko tavallisia matemaattisia alkeisfunktioita (x^p, sin, cos, log, arctan, ...) , hieman vähemmän tunnettuja, ns. erikoisfunktiota (erf, Γ, ...) tai Mathematican komentoja, jotka myös voidaan ajatella funktioiksi (Plot, Expand, TrigExpand, ...).

Käyttäjän määrittelemät funktiot

Käyttäjä voi itse määritellä Mathematicassa omat funktionsa, jotka määrittelyn jälkeen toimivat kuten mitkä tahansa valmiit funktiot. Määrittelyssä on vasemmalla funktion nimi, jossa muuttujien tulee olla ns. muodollisia parametreja. Näiden merkkinä on alaviiva. Tämän jälkeen on merkki := (tai vain yhtäläisyysmerkki; näiden välillä on pieni ero). Oikealla puolella annetaan funktion lauseke, jossa muodolliset parametri esiintyvät, mutta jossa ei enää saa käyttää alaviivoja.

f[x_] := Log[x] Sin[x]^2

f[3]

f[3. ]

f[a + b]

Plot[f[t], {t, 0, 10}]

D[f[x], x]

Derivaatalle voidaan käyttää myös lyhyempää merkintää pilkuttamalla tavanomaiseen tapaan:

f'[x]

f'[3]

f''[t]

Pilkkumerkintä soveltuu myös standardifunktioihin:

Sin'[x]

Sin''[x]

Myös usean muuttujan funktioita voidaan määritellä:

g[x_, 
        y_] :=  (1  +  Sin[x]^2)/(2  +  
            Exp[y])

g[a, 5/7]

g[3.0, 0.01]

Funktiot voidaan myös määritellä paloittain:

h[x_ /; x > 0] := Exp[x]

h[x_ /; x < 0] := Sin[5 x]

h[0] = 2

Plot[h[x], {x, -2, 2}]

Table[h[x], {x, -2, 2, 1/2}]

Vaihtoehtoinen tapa funktion määrittelemiseen on funktion Function käyttö:

ff = Function[t, Log[t] Sin[t]^2]

Tämä on sama kuin aluksi määritelty funktio f:

f[u] == ff[u]

Myös usean muuttujan funktiot ovat mahdollisia eikä arvojenkaan tarvitse olla lukuja:

gg = 
      Function[{x, y, n}, 
        Table[x^k y^(n - k), {k, 0, n}]]

gg[u, v, 5]

Rekursiiviset määrittelyt

Funktiomäärittelyt voivat olla myös rekursiivisia. Esimerkiksi Fibonacci'n luvut voidaan määritellä seuraavasti.

Aluksi määritellään kaksi alkuarvoa

a[0] = 1

a[1] = 1

ja tämän jälkeen rekursiivisesti loput, ts. ilmoitetaan, että seuraava on aina kahden edellisen summa:

a[n_] :=  a[n - 1]  +  a[n - 2]

Kysymysmerkillä voidaan katsoa, millainen määrittely funktiolle a on tallentunut:

?a

Määritelmän perusteella voidaan laskea lista Fibonacci'n lukuja:

Table[a[k], {k, 0, 25}]

Sam määrittely voidaan antaa se hieman erilaisessa muodossa, jolloin laskenta nopeutuu oleellisesti. Mistä oikeastaan on kysymys, jääköön ohjelmointihenkisten pohdittavaksi.

b[0] = 1

b[1] = 1

b[n_] :=  b[n] = b[n - 1]  +  b[n - 2]

?b

Laskentanopeudessa on todellakin huomattava ero:

Timing[a[30]]

Timing[b[30]]

Funktio Timing antaa paitsi tuloksen myös sen laskemiseen käytetyn ajan.