Simo K. Kivelä / 08.05.2003

Listat; vektorit ja matriisit

Remove["Global`*"]

Lista ja sen alkiot

Lista on tärkein Mathematican datatyyppi. Sillä on erilaisia käyttötapoja tavattoman paljon. Ensimmäisenä eteen tulevia ovat erilaiset taulukot ja toisaalta vektorit.

Lista voidaan yksinkertaisimmin muodostaa luettelemalla sen alkiot alkiot aaltosuluissa. Listan alkioihin voidaan viitata antamalla indeksi(t) kaksinkertaisissa hakasuluissa. Joissakin tapauksissa voidaan käyttää myös listaan kohdistettavia funktioita.

lista =  {a, b, c, d, e, f}

lista[[4]]

lista[[{2, 5, 6}]]

{Last[lista], First[lista]}

Listoja voidaan muodostaa Table- ja Range-funktiolla:

Table[k^2, {k, 1, 10}]

Range[5, 12]

Range[5, 12, 0.5]

Listat voivat olla useampikertaisia ja niiden käsittelyyn on käytettävissä melkoinen määrä funktioita; seuraavassa on vain muutama yksinkertainen esimerkki.

lst =  {{a}, {b, c}, {d, e, f}}

Length[lst]

Flatten[lst]

Length[Flatten[lst]]

Listat työkaluna

Listoja käytetään työkaluina monissa komennoissa. Jos nämä kohdistuvat esimerkiksi useaan yhtälöön, joissa on useita muuttujia tai tuntemattomia, nämä annetaan usein listoina.

yhtalo1 =  (x  -  1)^2  +  (y  -  
                3)^2  ==  5

yhtalo2 =  y ==  x^2

Kun yhtälöiden kuvaajat piirretään samaan kuvioon yhdellä käskyllä, annetaan yhtälöt listana. Piirtokäskyssä muuttujien vaihteluvälit annetaan myös listoina.

Needs["Graphics`ImplicitPlot`"]

ImplicitPlot[{yhtalo1, yhtalo2}, {x, -5, 5}, {y, -2, 
        6}]

Yhtälöparia ratkaistaessa yhtälöt annetaan listana, samoin tuntemattomat. Ratkaisu voidaan sijoitta johonkin lausekkeeseen poimimalla listana saatavasta ratkaisusta haluttu alkio.

rtk =  NSolve[{yhtalo1, yhtalo2},  {x, y}]

etaisyysorigosta =  
      Sqrt[x^2 + y^2] /. First[rtk]

etaisyydetorigosta =  
      Sqrt[x^2 + y^2] /. {First[rtk], rtk[[4]]}

Vektorit

Vektorit esitetään listoina. Esimerkkinä kaksi avaruusvektoria.

vektoriA =  {1, 2, 3}

vektoriB =  {4, 5, 6}

Vektorioperaatioille on omat symbolinsa: skalaaritulo esitetään pisteellä (tai kahden argumentin funktiolla Dot), vektoritulo funktiolla Cross. Näitä käyttäen voidaan suorittaa vektorialgebran laskuja.

skalaaritulo =  vektoriA . vektoriB

Dot[vektoriA, vektoriB]

valinenkulma =  
      ArcCos[vektoriA . vektoriB/Sqrt[vektoriA . vektoriA]/
          Sqrt[vektoriB . vektoriB]]

valinenkulma // N

valinenkulma/Degree // N

valinenkulma/(Pi/180) // N

vektoriC =  Cross[vektoriA, vektoriB]

vektoriA . vektoriC

vektoriB . vektoriC

Sqrt[vektoriC . vektoriC] ==  
      Sqrt[vektoriA . vektoriA] Sqrt[vektoriB . vektoriB] Sin[
          valinenkulma]

Skalaari- eli sisätulo muissa yhteyksissä

Skalaaritulo on käytettävissä myös mille tahansa listoille, joissa on yhtä monta alkiota. Listojen ei siis välttämättä tarvitse olla (2- tai 3-komponenttisia) vektoreita.

potenssit =  Table[x^k, {k, 0, 10}]

kertoimet =  Range[-5, 5]

Length[potenssit]  ==  Length[kertoimet]

polynomi =  kertoimet . potenssit

CoefficientList[polynomi, x]

Matriisit

Eräänlainen vektorin yleistys on matriisi. Tämä esitetään kaksinkertaisena listana. Ns. kaksiulotteinen tulostus voidaan saada aikaan kohdistamalla matriisiin funktio MatrixForm.

matriisiA =  {{1, a, a^2}, {1, b, b^2}, {1, c, 
          c^2}}

matriisiA // MatrixForm

matriisiB =  Table[i j, {i, 1, 3}, {j, 1, 5}]

matriisiB // MatrixForm

Matriisituloa merkitään pisteellä kuten skalaarituloakin:

matriisiC =  matriisiA . matriisiB

matriisiC // MatrixForm

Matriisista voidaan poimia alkioita indeksimekintää käyttäen:

matriisiA[[2, 3]]

matriisiA[[2]]

Matriiseihin voidaan kohdistaa erilaisia funktioita:

Transpose[matriisiA] // MatrixForm

determ =  Det[matriisiA]

Factor[determ]