Simo K. Kivelä / 28.04.2003

Mathematica numeerisena ja symbolisena laskimena

Mitä laskentaohjelmalta voi odottaa?

Periaatteessa interaktiivinen symbolinen laskentaohjelma on kuin laajennettu taskulaskin: voidaan laskea numeerisia arvoja lausekkeille, muokata (sieventää eri tavoin, derivoida, integroida jne.) symbolisia, ts. kirjaimia sisältäviä lausekkeita, laatia erilaisia graafisia esityksiä (funktioiden kuvaajia, tilastoja yms.), kirjoittaa ohjelmakoodeja ohjelman omalla kielellä, tallettaa syötteet ja tulosteet dokumentiksi, joka voidaan varustaa selittävillä teksteillä, jne. Dokumentti voidaan tulostaa paperille tai muuntaa www-sivuiksi. Tämä esitys on juuri tällainen dokumentti.

Laskentaohjelmat on perinteisesti jaettu numeerisiin ja symbolisiin. Edelliset laskevat ainoastaan numeerisia laskuja, jälkimmäiset kykenevät käsittelemään myös lausekkeita. Molemmissa on yleensä mahdollisuudet graafisten esitysten tekemiseen. Nykyään ero on hämärtynyt: symboliset ohjelmat ovat yleensä erittäin tehokkaita myös numeerisessa laskennassa, alunperin numeerisiin ohjelmiin on liitetty symbolisen laskennan mahdollistavia komponentteja.

Tunnetuimmat ja laajimpaan käyttöön levinneet symboliset ohjelmat ovat Mathematica ja Maple. Kolmantena kannattanee mainita muPad. Myös ilmaisia ohjelmia on saatavissa (esimerkiksi Maxima, Yacas), mutta ominaisuuksiltaan nämä ovat vaatimattomampia ja usein hieman vanhahtavia. Numeerisista ohjelmista merkittävimmät ovat Matlab ja Mathcad. Kummassakin on nykyään myös symbolisia ominaisuuksia, jotka ovat peräisin mukaan liitetyistä Maple-ohjelman komponenteista.

Tämä on Mathematica-dokumentti (notebook = muistikirja) ja esittelee Mathematica-ohjelman perusominaisuudet.

Yleistä

Ohjelma tallettaa muistiin kaikki syötteet ja välitulokset. Näihin voidaan missä tahansa laskennan vaiheessa viitata tulostuksen numerolla
(esimerkiksi Out[12] tai %12). Jos tulokselle on annettu nimi (mikä on suositeltavaa), siihen voidaan viitata myös tällä nimellä.

Pitkässä istunnossa saattaa aiheutua ongelmia siitä, että muistissa on vanhoja tuloksia talletettuna nimellä, jonka käyttäjä jo on unohtanut tai jonka hän kuvittelee tarkoittavan jotakin muuta. Tämän johdosta kannattaa uuteen tehtävään ryhdyttäessä muisti puhdistaa hieman kryptisellä komennolla:

Remove["Global`*"]

Numeerinen laskenta

Numeerisessa laskennassa voidaan käyttää periaatteessa mielivaltaisen monta numeroa. Käytännössä koneen muisti ja laskenta-aika asettavat rajoituksensa. Käytetty syntaksi on luonnollinen. Kertomerkki on joko välilyönti tai *; pois sitä ei voida (yleensä) jättää. Kuten seuraavat esimerkit osoittavat, pelkän välilyönnin käyttäminen ei ole kovin selkeätä ainakaan numeerisissa laskuissa.

12 13

12*13

Kertoma ilmaistaan tavalliseen tapaan huutomerkillä.

100!

Luku π syötetään nimellä Pi tai se voidaan valita valikosta. Funktiolla N sille voidaan laskea haluttu määrä desimaaleja. (Desimaaleja tunnetaan nykyään hieman yli 206 miljardia. Kovin monen desimaalin laskeminen tukkii Mathematican varsin tehokkaasti.)

Pi

Pi // N

N[Pi, 50]

Laskettuihin arvoihin voidaan myöhemmin viitata:

Out[3]

%3

%3/%4

Viittaamisesta tulee helpompaa, jos tuloksille annetaan nimet (mielellään mahdollisimman kuvaavat nimet, jolloin on itsekin helpompi muistaa, mitä mikin symboli tarkoittaa):

piipotneper25 =  N[Pi^E, 25]

puolikaspiipotneper25 = piipotneper25/2

2 puolikaspiipotneper25  -  piipotneper25

Jos syötteessä on desimaaliluku (jossa käytetään desimaalipistettä, ei -pilkkua), tulos lasketaan desimaalilukuna, muutoin lasketaan ns. tarkoilla arvoilla.

2^(1/2)

2^0.5

Myös funktioiden arvoja voidaan laskea:

Sin[2]

Sin[2] // N

Sin[2. ]

Sin[Pi/4]

Myös kompleksiluvuilla voidaan laskea:

(1 + I)^2

Sqrt[-1]

Exp[Sin[0.5 + 0.2 I]]

Exp[I Pi]

Symbolinen laskenta

Vastaavalla tavalla voidaan käsitellä algebrallisia lausekkeita, so. lausekkeita, joissa on kirjainsymboleja:

lsk =  (x  +  y)^12

Lausekkeita voidaan muokata, esimerkiksi sieventää useilla eri tavoilla. Ei ole itsestään selvää, mitä sievä kussakin tapauksessa tarkoittaa; se riippuu siitä, mitä lausekkeelle on seuraavaksi tarkoitus tehdä. Tämän johdosta sieventämiskomentoja on useita erilaisia eikä niiden hallinta aina ole helppoa. Kunkin komennon argumentti (lauske, johon operaatio kohdistuu) annetaan hakasuluissa. Tämä on yleinen tapa merkitä funktioita Mathematicassa; funktiotahan nämä komennotkin ovat. Esimerkkeinä lausekkeen kehittäminen, tekijöihin jako ja ns. osamurtokehitelmän muodostaminen; erilaisia sievennyskomentoja on kuitenkin paljon enemmän.

poly =  Expand[lsk]

Factor[poly]

lsk =  
      x/(-7 + 13 x - 26 (x^2) + 45 (x^3) - 49 (x^4) + 
            62 (x^5) - 60 (x^6) + 46 (x^7) - 41 (x^8) + 21 (x^9) - 
            10 (x^10) + 5 (x^11) + (x^12))

Apart[lsk]

Yleisiä sievennyskomentoja ovat Simplify ja FullSimplify. Mitä nämä tekevät, ei kuitenkaan ole aina selvää:

lsk1 =  (a^3 - b^3)/(a - b)

Simplify[lsk1]

lsk2 =  (a^15 - b^15)/(a - b)

Simplify[lsk2]

FullSimplify[lsk2]

Cancel[lsk2]

Funktioiden käsittelyyn liittyy omat sievennyskomentonsa:

TrigExpand[Sin[x + y]]

Kaikki yhden argumentin sievennyskomennot voidaan kirjoittaa myös argumentin jälkeen:

lsk2 // Cancel

Sin[x + y] // TrigExpand

Derivointi ja integrointi tapahtuvat yksinkertaisesti.

D[Exp[Sin[x]], x]

D[u[v[x]], x]

D[Log[x], {x, 2}]

Integrate[x^5 Exp[-x], x]

Integrate[x^5 Exp[-x], {x, 0, 1}]

Mathematica kuitenkin tuntee tavallisten alkeisfunktioiden lisäksi melkoisen määrän myös ns. erikoisfunktioita.

Integrate[Exp[-t^2], {t, 0, 2}]

Tälle saadaan myös numeerinen arvo:

% // N

Integrointi voi tapahtua myös numeerisesti:

NIntegrate[Exp[-t^2], {t, 0, 2}]

Virheellisiä tuloksia voi kuitenkin yllättäen syntyä. Jos integroidaan symbolisesti ja tuloksesta lasketaan numeerinen arvo, saatetaan saada eri tulos kuin integroimalla suoraan numeerisesti. Vielä Mathematican edellinen versio sai seuraavista syötteistä eri tulokset. Kyseessä on sinänsä ymmärrettävä ongelma, joka aiheutuu kyseisen erikoisfunktion (EllipticE) ominaisuuksista kompleksialueella. Mikään ohjelmisto tuskin on virheetön: uudessa versiossa on uudet virheet. Käyttäjän tulee siis oppia kriittisyyteen.

Integrate[Sqrt[2  -  Sin[x]^2], {x, 0, 2 Pi}]

% // N

NIntegrate[(Sqrt[2 - Sin[x]^2]), {x, 0, 2 π}]

Jälkimmäisessä syötteessä on käytetty pelkän näppäimistön sijasta myös Mathematican syötepaletteja.

Aina eivät sieventämiskomennot kuitenkaan ilman lisämääreitä anna sitä, mitä odottaisi. Syykin voi olla hyvä:

Simplify[Sqrt[x^2]]

Simplify[Sqrt[x^2], Element[x, Reals]]

Sqrt[2 I]

Mutta sieventää voidaan myös väkisin, ts. käyttäjän vastuulla:

PowerExpand[Sqrt[x^2]]