Simo K. Kivelä / 06.08.2001

Frégier'n lause ellipsille

Tehtävä

Ellipsin kehältä valitaan piste P. Tämän kautta asetetaan kaksi toisiaan vastaan kohtisuoraa suoraa, jotka leikkaavat ellipsin pisteen P lisäksi pisteissä A ja B. Osoita, että on olemassa suorien asennosta riippumaton piste Q, jonka kautta jana AB kulkee.

Ratkaisu

Remove["Global`*"]

Muodostetaan origokeskisen ellipsin yhtälö:

ellipsi =  x^2/a^2  +  y^2/b^2  ==  1

Jokainen tämän kehäpiste voidaan esittää seuraavassa muodossa:

P = {x0, y0} = {a Cos[t], b Sin[t]}

Kaikki ellipsin pisteet saadaan, kun parametrille t annetaan arvot väliltä [0, 2 π]. Pisteet todellakin toteuttavat ellipsin yhtälön:

ellipsi /. {x -> x0, y -> y0} // Simplify

Tämän pisteen kautta asetetaan kaksi toisiaan vastaan kohtisuoraa suoraa. Annetaan nämä vektorimuodossa, jolloin suuntavektorit voidaan kirjoittaa {p, q} ja {-q, p}. Vektoriesityksessä tarvittava parametri olkoon u:

suora1 =  {x, y} == {x0, y0} + u {p, q}

suora2 = {x, y} == {x0, y0}  +  u {-q, p}

Etsitään kummankin suoran ja ellipsin leikkauspisteet. Näitä on kummallakin suoralla kaksi ja niistä toinen on luonnollisesti ellipsillä oleva piste {(Subscript[x, 0]), (Subscript[y, 0])}, jonka kautta suorat asetettiin. Sievennetään ratkaisujen lausekkeet.

rtk1 =  Solve[{ellipsi, suora1}, {x, y, u}] // 
            FullSimplify // PowerExpand // 
        FullSimplify

rtk2 =  Solve[{ellipsi, suora2}, {x, y, u}] // 
            FullSimplify // PowerExpand // 
        FullSimplify

Edellisessä tapauksessa jälkimmäinen ratkaisu antaa suorien yhteisen pisteen. Jälkimmäisessä tapauksessa tämä on edellinen. Talletetaan saatujen toisten leikkauspisteiden koordinaatit omille nimilleen:

A = {x1, y1} =  {x, y} /. First[rtk1]

B = {x2, y2} =  {x, y} /. Last[rtk2]

Saadut kaksi pistettä määräävät suoran. Tällöin ellipsin sisään syntyy suorakulmainen kolmio, jonka hypotenuusana on viimeksi muodostettu suora. Hypotenuusasuoran tavanomainen yhtälö:

AB =  
      y  -  y1 ==  (y2 - y1)/(x2 - x1) (x  -  
              x1)

Jotta tilanteesta voidaan piirtää kuvio, ilmoitetaan Mathematicalle, että tarvitaan lisäpaketti:

Needs["Graphics`ImplicitPlot`"]

Muodostetaan kohtisuorien suorien tavanomaiset yhtälöt eliminoimalla vektoriesityksestä parametri:

PA =  Eliminate[suora1, u]

PB =  Eliminate[suora2, u]

Kuvio piirretään seuraavilla lukuarvoilla:

numarvot =  {a -> 3,  b ->  2,  t ->  1.2,  p -> 2, 
        q -> 3}

kuva1 =  
      ImplicitPlot[
        Evaluate[{ellipsi, PA, PB,  AB} /. numarvot], {x, -5, 
          5}, {y, -5, 5}]

Kuvaan voidaan myös lisätä tekstit ja merkitä piste P:

tekstit =  
      Graphics[{Text["A", A, {0, -2}], 
            Text["B", B, {0, -2}], 
            Text["P", P, {0, -2}], PointSize[0.03], 
            Point[P]} /. numarvot]

Show[kuva1, tekstit]

Frégier'n lause väittää, että suora AB kulkee aina saman pisteen kautta riippumatta kohtisuorien suorien asennosta; ellipsin piste P, jonka kautta kohtisuorat asetetaan, pidetään kuitenkin kiinteänä.

Lause voidaan todistaa asettamalla kohtisuorat toiseen asentoon ja määrittämällä tätä tilannetta vastaava jana AB. Jos saatujen kahden AB-janan leikkauspiste ei riipu suuntavektorista {p, q}, lause on todistettu.

Muodostetaan toinen AB-suora mahdollisimman yksinkertaisesti:

A2B2 =  AB /. {p -> r, q -> s}

Ratkaistaan AB-suorien leikkauspiste ja sievennetään se:

rtk =  Solve[{AB, A2B2}, {x, y}];

Q =  {x, y} /. rtk[[1]] // Simplify

Tulos on todellakin riippumaton symboleista p, q, r ja s, ts. kohtisuorien suoraparien suunnista.

Ratkaisu ei luonnollisestikaan mene edellä esitetyllä tavalla, jos p  =  r ja q  =  s. Tätä ei laskussa ole mitenkään suljettu pois. Mathematica kuitenkin käsittelee tällaisessa tilanteessa ns. geneeristä tapausta, ts. tapausta, missä mitään rajoittavia erikoisehtoja ei vallitse.

Frégier'n lause on siis saatu todistetuksi.

Esimerkkitapauksessa hypotenuusasuorien leikkauspiste on

numQ =  Q /. numarvot

Kuvio:

numarvot2 =  {a -> 3,  b ->  2,  t ->  1.2,  p -> 3, 
        q -> 1}

kuva2 =  
      ImplicitPlot[
        Evaluate[{ellipsi, PA, PB,  AB} /. numarvot2], {x, -5, 
          5}, {y, -5, 5}]

Show[kuva1, kuva2, 
      Graphics[{PointSize[0.03], Point[numQ], 
          Point[P] /. numarvot}]]

Animaatio:

Table[
      Show[Graphics[{ImplicitPlot[
                Evaluate[{ellipsi, PA, PB,  AB} /. {a -> 3,  
                      b ->  2,  t ->  1.2,  p -> Cos[w], 
                      q -> Sin[w]}], {x, -5, 5}, {y, -5, 5}, 
                DisplayFunction -> Identity][[1]], {PointSize[
                0.03], Point[numQ], 
              Point[P] /. {a -> 3,  b ->  2,  t ->  1.2,  
                  p -> Cos[w], q -> Sin[w]}}}, 
          PlotRange -> {{-5, 5}, {-5, 5}}], 
        DisplayFunction -> $DisplayFunction, AspectRatio -> 1], {w, 
        0, Pi/2, Pi/48}]

Lisäongelma

Lisäongelmana voidaan pohtia seuraavaa: Edellä esitetyn mukaisesti jokaista ellipsin kehän pistettä kohden saadaan AB-suorien leikkauspiste. Jos kehäpiste kiertää koko ellipsin, millaisen käyrän piirtää hypotenuusasuorien leikkauspiste?

Leikkauspiste on edellä lasketun mukaisesti

Q

Tämä on itse asiassa etsityn käyrän parametriesitys parametrina t. Käyrän yhtälö saadaan eliminoimalla parametri yhtälöistä

paramyhtalot =  {x  ==  Q[[1]],  
        y  ==  Q[[2]]}

Eliminointi tapahtuu esimerkiksi seuraavasti:

yhtalot =  
      Flatten[{paramyhtalot /. {Sin[t] -> s, Cos[t] -> c}, 
          s^2 + c^2 == 1}]

kayra =  Eliminate[yhtalot, {s, c}]

Lopuksi kuvio, jossa on sekä alkuperäinen ellipsi että etsitty uusi käyrä, joka myös on ellipsi:

ImplicitPlot[
      Evaluate[{ellipsi, kayra[[1]]} /. numarvot], {x, -5, 
        5}, {y, -5, 5}]